# Maintainer: Sahil Gautam <printfdebugging@gmail.com>

_realname=bear
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=4.1.3
pkgrel=1
pkgdesc='A tool that generates a compilation database for clang tooling (mingw-w64)'
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url='https://github.com/rizsotto/Bear'
msys2_repository_url='https://github.com/rizsotto/Bear'
msys2_references=(
    'archlinux: bear'
)
license=('spdx:GPL-3.0-or-later')
makedepends=("${MINGW_PACKAGE_PREFIX}-rust")
options=('!strip')
source=("${url}/archive/${pkgver}/${_realname}-${pkgver}.tar.gz")
sha256sums=('87a5b385b01000a3ae2c69f535384dca33da7f23925a523ba177f98b1bb7f301')

prepare() {
    cd "${_realname}-${pkgver}"

    cargo fetch --locked --target "${RUST_CHOST}"
}

build() {
    cd "${_realname}-${pkgver}"

    cargo build --frozen --release
}

check() {
    cd "${_realname}-${pkgver}"

    cargo test --frozen --release
}

package() {
    cd "${_realname}-${pkgver}"

    DESTDIR="${pkgdir}" PREFIX="${MINGW_PREFIX}" sh scripts/install.sh
}
