Indhold

# AGGREGER-funktion

Denne funktion returnerer et sammendraget resultat af beregningen i området. Du kan benytte forskellige sammendragsfunktioner som oplistet herunder. AGGREGER-funktionen (sammendragsfunktionen) giver dig mulighed for at udelade skjulte rækker, fejl, SUBTOTAL (delsammentælling) og andre sammendragsfunktioner i beregningen.

AGGREGER-funktionen (sammendragsfunktionen) bruges på lodrette områder af data med aktiveret AutoFilter. Hvis AutoFilter ikke er aktiveret vil automatisk genberegning af funktionen ikke virke for nyligt skjulte rækker. Det er ikke meningen at funktionen skal virke på vandrette områder, men kan godt bruges, dog med visse begrænsninger. Specielt vil AGGREGER-funktionen tilknyttet et vandret område ikke respektere at skjule kolonner, men undgår korrekt fejl og resultater af SUBTOTAL og andre sammendragsfunktioner inde i rækken.

### Syntaks

SAMMENDRAG(Funktion; Indstillinger; Reference 1[; Reference 2][; ... ;[Reference 253]])

eller

SAMMENDRAG(Funktion; Indstillinger; Matrix[; k])

Funktion – obligatorisk argument. Et funktionsindeks eller en reference til en celle med værdi fra 1 til 19, jf. følgende tabel.

Funktionsindeks | Benyttet funktion
--- | ---
1 | MIDDEL
2 | TÆL (på engelsk: COUNT)
3 | TÆLV
4 | MAKS
5 | MIN
6 | PRODUKT (på engelsk: PRODUCT)
7 | STDAFV.S (på engelsk: STDEV.S)
8 | STDAFV.P (på engelsk: STDEV.P)
9 | SUM
10 | VARIANS.S
11 | VARIANS.P
12 | MEDIAN
13 | HYPPIGST.ENKELT (på engelsk: MODE.SNGL)
14 | STØRSTE (på engelsk: LARGE)
15 | MINDSTE (på engelsk: SMALL)
16 | FRAKTIL.MEDTAG (på engelsk: PERCENTILE.INC)
17 | KVARTIL.MEDTAG (på engelsk: QUARTILE.INC)
18 | FRAKTIL.UDELAD (på engelsk: PERCENTILE.EXC)
19 | KVARTIL.UDELAD (på engelsk: QUARTILE.EXC)

Valg – obligatorisk argument. Et valgindeks eller reference til en celle med værdi fra 0 til 7 afgør hvad der skal ignoreres i funktionen.

Valg-indeks | Tilknyttet valg
--- | ---
0 | Ignorér kun indlejrede SUBTOTAL- og SAMMENDRAG-funktioner
1 | Ignorér kun skjulte rækker, indlejrede SUBTOTAL- og SAMMENDRAG-funktioner
2 | Ignorér kun fejl samt indlejrede SUBTOTAL- og SAMMENDRAG-funktioner
3 | Ignorér skjulte rækker, fejl samt indlejrede SUBTOTAL- og SAMMENDRAG-funktioner
4 | Ignorér intet
5 | Ignorér kun skjulte rækker
6 | Ignorér kun fejl
7 | Ignorér kun skjulte rækker og fejl

Tal1 – påkrævet argument. Det første numeriske argument (hvis området er sat af en liste over værdier i funktionen) eller som en reference til den celle, som indeholder den.

Tal 2, 3, ... – valgfri. Et numerisk argument eller en reference til en celle (op til 253 argumenter), hvis sammendragne værdi, du har brug for.

matrix – påkrævet argument. Matrixen kan angives af områdets grænser, navnet på et navngivet område eller kolonneoverskriften.

For at bruge kolonneetiketten skal funktionen "Automatisk find kolonne- og rækkeetiketter" være aktiveret.

k – obligatorisk argument i de følgende funktioner: STØRSTE, MINDSTE, FRAKTIL.MEDTAG, KVARTIL.MEDTAG, FRAKTIL.UDELAD, KVARTIL.UDELAD (på engelsk: LARGE, SMALL, PERCENTILE.INC, QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC). Det er et numerisk argument, som skal svare til det andet argument i disse funktioner.

### Eksempler

| A | B | C
1 | KolonneEt | KolonneTo | KolonneTre
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #VÆRDI! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

SAMMENDRAG(4;2;A2:A9)
Returnerer maksimumværdien for området A2:A9 = 34.

=SAMMENDRAG(9;5;A5:C5)
Returnerer summen for området A5:C5 = 29, selv om nogle af kolonnerne er skjulte.

=SAMMENDRAG(9;5;B2:B9)
Returner summen af kolonnen B = 115. Hvis nogen række er skjult vil funktionen se bort fra dens værdi, for eksempel hvis den syvende række er skjult, vil funktionen returnere 95.

Hvis du behøver at anvende funktionen med et 3D-område, viser dette eksempel, hvordan det gøres.

=SAMMENDRAG(13;3;Ark1.B2:B9:Ark3.B2:B9)
Funktionen returnerer tilstand af værdierne af anden kolonne, fra arkene 1:3 (der har de samme data) = 8.

Du kan referere til en celle eller et område for hvert enkelt argument i formlen. Følgende eksempel viser hvordan. Desuden viser eksemplet at du kan bruge kolonneetiketter til at definere arealet.

=SAMMENDRAG(E3;E5;'ColumnOne')
Hvis E3 = 13 og E5 = 5, så returnerer funktionen tilstanden af den første kolonne = 10.

#### Tekniske oplysninger

Denne funktion er tilgængelig siden LibreOffice 4.4.

Denne funktion er IKKE en del af standarden Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Navnerummet er

COM.MICROSOFT.AGGREGATE

Relaterede emner

Wikiside for funktionen SAMMENDRAG (på engelsk: AGGREGATE).

MIDDEL (på engelsk: AVERAGE), TÆL (på engelsk: COUNT), TÆLV (på engelsk: COUNTA), MAKS (på engelsk: MAX), MIN (samme navn på engelsk), PRODUKT (på engelsk: PRODUCT), STDAFV.S (på engelsk: STDEV.S), STDAFV.P (på engelsk: STDEV.P), SUM (samme navn på engelsk), VARIANS.S (på engelsk: VAR.S), VARIANS.P (på engelsk: VAR.P), MEDIAN (samme navn på engelsk), HYPPIGST.ENKELT (på engelsk: MODE.SNGL), STØRSTE (på engelsk: LARGE), MINDSTE (på engelsk: SMALL), FRAKTIL.MEDTAG (på engelsk: PERCENTILE.INC) , KVARTIL.MEDTAG (på engelsk: QUARTILE.INC), FRAKTIL.UDELAD (på engelsk: PERCENTILE.EXC), KVARTIL.UDELAD (på engelsk: QUARTILE.EXC)

Find kolonne og række etiketter automatisk

Støt os venligst!