Plot 0
	name <The Artifact>

	% The PC has apparently been looking for an artifact.
	% A noted archeologist has been murdered. The PC can meet
	% his grad student and learn about a ruin. Going into the
	% ruin, the PC can find an item. The student will tell the
	% PC that only Kaema in Hwang-Sa temple can identify what
	% it is. The PC must then head to Hwang-Sa, but will be
	% attacked by his enemy along the way.

	% - Edited to v0.901 "light" standard

	% E1 is the scene for this episode
	element1 <Grab 3>

	% E2 is the scene for the next episode
	element2 <Scene Town Target !Far 1>

	% E3 is the grad student who will give the mission
	Element3 <Prefab>

	% E4 is the dead professor; needed just for a name
	Element4 <Prefab>

	% E5 is Kaema
	Element5 <Character>
	Stat 5 1506

	% E6 is your enemy
	Element6 <Prefab>

	% E7 is the artifact
	Element7 <Prefab>

	% V1 = Initialization Counter

	Init_Start <ifKeyItem E7 else GoCheckDelete S= 105 -1 N= 3 EScene 5 History 101 XRMystery NAV_XRMResolved AdvancePlot 1>
	start <ifKeyItem E7 else GoCheckDelete S= 105 -1 N= 3 EScene 5 History 101 XRMystery NAV_XRMResolved AdvancePlot 1>
	GoCheckDelete <ifPersona E3 else GoDelete ifPersona E5 else GoDelete ifItemOK E7 else GoDelete if= V1 0 V= 1 1 News d3 ifPersona N1 else GoN1Dead DeleteChar E6 E= 6 N1>
	GoN1Dead <N= 1 E6 FreezeChar E6>
	GoDelete <S= 101 1 AdvancePlot 0>

	% Msg1 <Renowned archaeologist \ELEMENT 4 in \ELEMENT 1 has been murdered. Guardians search for clues.>
	Msg1 <\ELEMENT 1 に住む有名な考古学者 \ELEMENT 4 が殺害された。Guardiansは手がかりを探している。>
	% Msg2 <History professor \ELEMENT 4 in \ELEMENT 1 has been found murdered. Guardians suspect antiquities smugglers.>
	Msg2 <\ELEMENT 1 に住む歴史的な教授 \ELEMENT 4 が他殺体で発見された。Guardiansは骨董品密輸団の仕業ではないかと疑っている。>
	% Msg3 <Famed archaeologist \ELEMENT 4 has been murdered by antiquities smugglers in \ELEMENT 1 . Guardians search for leads.>
	Msg3 <有名な考古学者 \ELEMENT 4 が \ELEMENT 1 で骨董品密輸団により殺害された。Guardiansは手がかりを探している。>

	% Msg101 <You discovered a mysterious emerald in the \ELEMENT 1 ruins.>
	Msg101 <\ELEMENT 1 の遺跡から不思議なエメラルドを発見した。>

sub
	Persona 3
	% V1 = Initialization
	% The grad student. Phase one: PC must locate the artifact.
	% rumor <!3 was a student of the murdered professor.>
	rumor <!3 は殺された教授の教え子だ>
	greeting <NewChat if= V1 1 else GoCheckFirst Say 7 AddChat 5 AddChat 6>
	GoCheckFirst <if= P1 1 else GoNotYet Say 1 AddChat 1 AddChat 2>
	GoNotYet <SayAnything>
	result1 <NewChat Say 2 AddChat 3>
	result2 <NewChat Say 3 AddChat 3>
	result3 <NewChat Say 4 V= 1 1 AddChat 4 Memo 6>
	result4 <NewChat Say 5 AddChat 5 AddChat 6>
	result5 <EndChat Say 9 SavePos LoadD .scene PassVar 1 E7 PassVar 2 S103 PassVar 3 5 PassVar 4 4 SeekGate -1>
	.scene <SCENE_ItemDungeon.txt>
	result6 <NewChat Say 8>
	% Msg1 <I can't believe what happened to Professor \ELEMENT 4 ... Who would do such a thing?>
	Msg1 <私は \ELEMENT 4 教授の身に起こったことを信じられません…。だれがあんなことを？>
	% Msg2 <It's been all over the news. Some thieves killed the professor and ransacked \PPR E4 office. It doesn't make sense. We haven't discovered anything valuable in the ruins; there's probably nothing valuable there.>
	Msg2 <この事件は世間でニュースになっていますよ。教授を殺害し \PPR E4 の研究室をあさった盗賊がいます。そんなことをしても無駄なのに。あの遺跡では何も貴重なものは見つかっていません。たぶんあそこには何も価値のあるものはないでしょう。>
	% Msg3 <\ELEMENT 4 was a great researcher. It makes no sense that \OPR E4 was killed... The ruin we're exploring is a cultural dig site. We haven't discovered anything valuable; there's probably nothing valuable there.>
	Msg3 <\ELEMENT 4 先生は偉大な研究者でした。先生が殺される理由は見当たりません…。私たちが探索している遺跡は文化的な発掘現場です。あの遺跡では何も貴重なものは見つかっていません。たぶんあそこには何も価値のあるものはないでしょう。>
	% Msg4 <They're just outside of town. We've explored down to about \VAL S103 meters deep; \ELEMENT 4 wouldn't let us dig past that... \OPR E4 said there were too many monsters past that depth.>
	Msg4 <その遺跡は町のすぐ外にあります。私たちは地下およそ \VAL S103 メートルまで探索しました。 \ELEMENT 4 先生からそれ以上は掘るなと言われていました…。先生によれば、その深さを過ぎれば怪物がたくさん出るそうです。>
	% Msg5 <I don't see why not. Our expedition here is finished... If you could find anything that we missed, that could be very useful. Would you like to go there now, or do you need to prepare?>
	Msg5 <もちろんです。その遺跡の探索は終わりましたから…。もし私たちが見逃したものを見つけたら、それはあなたの役に立つかもしれません。今すぐ遺跡へ行きますか？それとも準備する必要がありますか？>
	% Msg6 <The ruins in \ELEMENT 1 have been explored to \VAL S103 meters deep, but no farther.>
	Msg6 <\ELEMENT 1 の遺跡は地下 \VAL S103 メートルまで探索されたが、それ以上は調べられていない。>
	% Msg7 <Do you want to explore the ruins?>
	Msg7 <あの遺跡を探索しにいきますか？>
	% Msg8 <It's pretty dangerous down there, so you'll want to make sure everything is in top shape before you head down.>
	Msg8 <あの遺跡は非常に危険ですから、行く前に万全を期してください。>
	% Msg9 <Be careful. The place is crawling with monsters and all kinds of other nasty things... If you get past your depth come back up.>
	Msg9 <お気をつけて。現場には怪物がたくさんおり、その他の様々な厄介事もたくさんあります…。もし潜り過ぎたら戻って来るといいでしょう。>
	% Prompt1 <What happened here?>
	Prompt1 <ここで何があった？>
	% Prompt2 <Tell me about the professor.>
	Prompt2 <その教授について教えてくれ。>
	% Prompt3 <Tell me about the ruins.>
	Prompt3 <その遺跡について教えてくれ。>
	% Prompt4 <Can I see the ruins?>
	Prompt4 <遺跡を見せてくれる？>
	% Prompt5 <I'm ready to go.>
	Prompt5 <行ける%JG。>
	% Prompt6 <Maybe I should get ready first.>
	Prompt6 <まずは準備を整えないと。>

Plot 1
	% The PC has recovered the artifact, and now heads back to
	% the surface.

	% V1 = Combat recharge indicator
	% V10 = Told NPC don't have item

	Init_Start <ifPersona E5 else GoDelete>
	start <ifPersona E5 else GoDelete if= V1 -1 else goCheckCombat V= 1 1 ForceChat E6>
	GoCheckCombat <if= SceneID 1 else GoCheckTown if= V1 0 Block V= 1 -1 Alert 1 SavePos Dynamic 2 Threat S103 90 .nu1 .nu2>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Return>
	GoCheckTown <ifScene .scene V= 1 0>
	.scene <TOWN>
	GoDelete <S= 101 1 AdvancePlot 0>

	% Msg1 <While exiting town, you are attacked by mecha!>
	Msg1 <町を出ようとすると、メックに襲われた！>

sub
	Persona 3
	% The grad student; will tell the PC to go to Hwang-Sa.
	greeting <NewChat if= V1 0 else GoBeenBefore Say 1 AddChat 1 AddChat 2>
	GoBeenBefore <SayAnything>
	result1 <NewChat Reputation 3 d8 Reputation 2 1   V= 1 1  XPV 100  Say 2 Memo 4 AddChat 3>
	result2 <NewChat Reputation 3 -d8 Reputation 2 -1 V= 1 1  XPV 100  Say 3 Memo 5 AddChat 4>
	result3 <NewChat Say 6>
	result4 <goto result3>
	% Msg1 <You had a pretty long expedition down there. Some of the researchers thought you might've been eaten by a cave snail. Did you find anything interesting?>
	Msg1 <かなり長丁場の探索だったようですね。研究生の中にはあなたが洞窟カタツムリに食べられたのではないかと思っていた人もいましたよ。何か興味深いものは見つかりましたか？>
	% Msg2 <Wow... we haven't found anything else like that on the entire dig! It might be important. Your best bet would be to bring it to the archivist at Hwang-Sa temple to have it identified.>
	Msg2 <何と…。我々の発掘ではそのようなものは見つかりませんでした！それは重要なものかもしれません。それを Hwang-Sa 寺院の記録保管人のところへ持って行き鑑定してもらうのが最良の策でしょう。>
	% Msg3 <That's really disappointing. Since you left, an archivist from Hwang-Sa temple has been asking about the ruin. If you had found anything, they might have been interested in financing further exploration.>
	Msg3 <それはがっかりですね。あなたが出かけてから、Hwang-Sa 寺院の記録保管人から遺跡について聞かれていました。もしあなたが何かを見つけていれば、彼らは探索続行に出資する気になったかもしれません。>
	% Msg4 <You should bring the emerald to Hwang-Sa temple to have it identified.>
	Msg4 <例のエメラルドを Hwang-Sa 寺院へ持って行き鑑定してもらわなければならない。>
	% Msg5 <An archivist from Hwang-Sa temple has been inquiring about the \ELEMENT 1 ruins.>
	Msg5 <Hwang-Sa 寺院の記録保管人が \ELEMENT 1 遺跡について質問をしている。>
	% Msg6 <Hwang-Sa Temple has the largest archive of PreZero cultural artifacts on the planet. They're the chief research institution in this field... And it doesn't hurt that they pay top dollar for interesting finds.>
	Msg6 <Hwang-Sa 寺院は地球上で最も大きな旧紀の文化遺産保管所であり、この分野で最高の研究機関です…。彼らは興味深い発見になら大金を支払っても構わないようです。>
	% Prompt1 <I found this emerald!>
	Prompt1 <このエメラルドを見つけた！>
	% Prompt2 <No, nothing worth reporting...>
	Prompt2 <いや、報告に値するものは何も…。>
	% Prompt3 <Why Hwang-Sa temple?>
	Prompt3 <なぜ Hwang-Sa 寺院に？>
	% Prompt4 <Why would they be interested?>
	Prompt4 <なぜ彼らが出資する気になるんだ？>


	Persona 5
	% Kaema; will explain to the PC about the gem.
	% rumor <!5 knows a lot about PreZero artifacts.>
	rumor <!5 は旧紀の人工物に詳しい>
	greeting <NewChat say 1 AddChat 1 ifKeyItem E7 else GoNoKey AddChat 2>
	GoNoKey <ifItemOK E7 else GoKeyGone AddChat 3>
	GoKeyGone <AddChat 4>
	result1 <NewChat Say 2>
	result2 <NewChat Say 3 AddChat 5  DeleteKeyItem E7  V= 1 Reward Threat S103 300 500 CashPrize V1 History 9 Goto GoEndMission>
	result3 <NewChat Say 4>
	result4 <NewChat Say 5 AddChat 5 Reputation 1 -1 Reputation 6 -10 goto GoEndMission>
	result5 <NewChat History 8 ifG PCRep 1 0 else GoR5NoHero Say 6>
	GoR5NoHero <Say 7>
	GoEndMission <S= 101 1 S+ 102 1 N= 3 E2 S= 105 -1  AdvancePlot 0>
	% Msg1 <I've heard a rumor that you went exploring in the \ELEMENT 1 ruins. We are searching for an item from there, an ancient emerald. If you have found this I would be most glad to purchase it from you and tell you of its history.>
	Msg1 <あなたが \ELEMENT 1 遺跡へ探索に行ったという噂を聞きました。我々はそこである物、つまり古代のエメラルドを探しています。もしあなたがそれを見つけたのなら、私は喜んでそれを買い取り、それにまつわる歴史について語ってあげましょう。>
	% Msg2 <I get the feeling that you're in denial, either to yourself or just to me. Come back sometime when you are ready for some knowledge.>
	Msg2 <あなたは私を、そして自分をも拒んでいるように思います。いつか知る用意ができたらまた来なさい。>
	% Msg3 <Ah, so you have it! This is a great relief to me; I had feared the worst. Here, you should be properly rewarded for recovering this gem.>
	Msg3 <おや、お持ちではありませんか！大いに安心しました。最悪の事態を心配していましたから。どうぞ、この宝石を取ってきてくださったことに対して適切な報酬を受け取ってください。>
	% Msg4 <You left the Emerald somewhere unguarded? Hurry, go retrieve it... It is very important that it not fall into the wrong hands!>
	Msg4 <あなたはそのエメラルドを放置してきたのですか？急いで取りに行きなさい…。絶対にそれを間違った人物の手に渡してはなりません！>
	% Msg5 <Not anymore? Then all may be lost... The Emerald was safe when it was hidden deep in the ruin, but now it will be found by those who intend to use it for evil!>
	Msg5 <もう持ってないですって？ではもう手に入らないかもしれませんね…。遺跡深くに隠されている時には例のエメラルドも安全だったでしょうが、今はもうそれを悪事に使おうとする輩に見つかってしまうでしょう！>
	% Msg6 <The Magnus Emerald is an AI core from the Age of Superpowers. It was in charge of a weapons project seeking to replace the Cyclops biosoldiers. Cetus was the final prototype for this line; the Emerald has knowledge of the others as well.>
	Msg6 <Magnusエメラルドは超大国時代に作られたＡＩコアです。それが作られたのはCyclops生物兵士に代わる兵器開発計画です。その計画の最終試作体が Cetus です。このエメラルドを調べれば他のことも分かるでしょう。>
	% Msg7 <All you need to know is that it is a source of dark knowledge from PreZero times, and in the wrong hands it could do very great harm to this world.>
	Msg7 <あなたが知らなければならないのは、これは旧紀の時代の悪しき知識の源であり、間違った人物の手に渡ればこの世界にとって大きな害を及ぼしうるということだけです。>
	% Msg8 <You learned that the Magnus Emerald is a source of dark knowledge.>
	Msg8 <Magnusエメラルドは邪悪な知識の源だと分かった。>
	% Msg9 <You sold the Emerald to Kaema of Hwang-Sa Temple for $ \VAL V1 .>
	Msg9 <Magnusエメラルドを Hwang-Sa 寺院の Kaema に $ \VAL V1 で売却した。>
	% Prompt1 <That's none of your business.>
	Prompt1 <%JSには関係ない。>
	% Prompt2 <Here it is, right here. [give Emerald]>
	Prompt2 <どうぞ。[エメラルドを渡す]>
	% Prompt3 <I don't have it now, but I can get it!>
	Prompt3 <今は持っていないが、取りには行ける%JG！>
	% Prompt4 <I don't have that anymore.>
	Prompt4 <もう持っていない%JG。>
	% Prompt5 <Can you tell me why it's so important?>
	Prompt5 <どうしてそれがそんなに重要なんだ？>

	Persona 6
	% The PC's enemy; will attack the PC regularly.
	greeting <EndCHat Say d5 ifKeyItem E7 else GoNoItem AddChat d3>
	GoNoItem <if= P10 0 AddChat 4>
	Result1 <EndChat V= 2 6 V+ 2 d4 Say V2>
	result2 <Goto Result1>
	result3 <Goto Result1>
	result4 <EndChat P= 10 1 Say 6>
	% Msg1 <I know that you've found it... so hand it over and you won't have to die!>
	Msg1 <%JSが例のものを見つけたのは知っている%JG…それを渡せば死ななくて済むぞ！>
	% Msg2 <I know what you found in \ELEMENT 1 and I want it!>
	Msg2 <%JSが \ELEMENT 1 で何を見つけたかは知っている%JG。それをよこせ！>
	% Msg3 <You took something from the ruins in \ELEMENT 1 . Well, it should be mine! I will take it!>
	Msg3 <%JSは \ELEMENT 1 の遺跡から取ってきたものを持っているようだな。そう、それは%JFが手に入れるべきものだ！渡してもらおう！>
	% Msg4 <You're carrying precious cargo. I want it!>
	Msg4 <%JSは貴重なものを持っているようだな。それをよこせ！>
	% Msg5 <You found something in \ELEMENT 1 that we've been searching for. I intend to take it!>
	Msg5 <%JSは我々が探し求めているものを \ELEMENT 1 で見つけたようだな。それを渡してもらおう！>
	% Msg6 <Ha, you're not a very convincing liar... Since you don't have the courtesy to just hand it over, we'll have to take it from your dead body!!!>
	Msg6 <フン、%JSは嘘をつくのが下手だな…。丁重に渡す気がないのなら、%JSの死体から剥ぎ取ることになる！>
	% Msg7 <My henchmen will take the emerald from your corpse!>
	Msg7 <%JFの部下が%JSの屍から例のエメラルドを剥ぎ取るだろう！>
	% Msg8 <Good, there's going to be a fight... my henchmen will be able to defeat you easily.>
	Msg8 <いいだろう、それなら力ずくで奪うまでだ…。%JFの部下なら%JSなどたやすく始末できるだろう。>
	% Msg9 <Whether you give it to us or whether we have to kill you to get it makes no matter to me.>
	Msg9 <%JSがそれを我々に渡しても、我々が%JSを殺してそれを奪っても、%JFにとっては同じことだ。>
	% Msg10 <You will not live long enough to find out what power the emerald actually holds...>
	Msg10 <%JSはそのエメラルドの持つ真の力を理解する前に死ぬのだ…。>
	% Prompt1 <No way! It's mine!>
	Prompt1 <断る！これは%JFのものだ！>
	% Prompt2 <Get lost, \ELEMENT 6 .>
	Prompt2 <失せろ、 \ELEMENT 6 。>
	% Prompt3 <Just try and get it.>
	Prompt3 <取れるものなら取ってみろ。>
	% Prompt4 <I don't have anything! Honest!>
	Prompt4 <%JFは何も持っていない%JG！本当だ！>

% Plot 1
end

% Plot 0
end
inv
	NPC Professor
	CharDesc Young
	job <Grad Student>
	place <1 PASS>

	NPC Professor

	NPC Mecha Pilot
	EquipChar 25000

	Treasure 1000
	% name <Magnus Emerald>
	name_org <Magnus Emerald>
	name <Magnusエメラルド>
	Clue37 <Print 1>
	% Msg1 <Peering into this gem, you can see faint geometric patterns embedded into the material. It looks like a computer circuit.>
	Msg1 <この宝石をのぞき込むと、その中に幾何学模様が埋め込まれているのがかすかに見えた。これはコンピュータの回路のようだ。>
	Clue29 <Print 2>
	% Msg2 <This gemstone appears to be an old style AI computer core. Examining it more closely, you make out faint geometric patterns embedded into the material.>
	Msg2 <この宝石は古い型のＡＩコンピュータコアのようだ。より詳しく調べてみると、宝石の中に幾何学模様が埋め込まれているのをかすかだが見ることができた。>

end
