# Maintainer: Alexey Pavlov <alexpux@gmail.com>
# Contributor: Martell Malone <martellmalone@gmail.com>

_realname=tools
_mingw_suff=mingw-w64-cross
pkgname=("${_mingw_suff}-${_realname}")
provides=("${_mingw_suff}-${_realname}-git")
conflicts=("${_mingw_suff}-${_realname}-git")
replaces=("${_mingw_suff}-${_realname}-git")
pkgdesc="MinGW-w64 headers for cross-compiler"
pkgver=11.0.1.r750.g05598db99
pkgrel=1
arch=('i686' 'x86_64')
url="https://mingw-w64.sourceforge.io/"
license=('custom')
groups=("${_mingw_suff}-toolchain" "${_mingw_suff}")
makedepends=('git' 'autotools' "${_mingw_suff}-gcc" "${_mingw_suff}-binutils")
options=('!strip' '!libtool' '!emptydirs' '!buildflags')
_commit='05598db991767e79b3d701ca0979df050d82eb11'
source=("mingw-w64"::"git+https://git.code.sf.net/p/mingw-w64/mingw-w64#commit=$_commit")
sha256sums=('SKIP')
msys2_references=(
  # doesn't exist in arch, this is the next best thing
  'archlinux: mingw-w64-headers'
)
_tools="gendef genidl genpeimg" #widl

_targets="i686-w64-mingw32 x86_64-w64-mingw32"

pkgver() {
  cd "${srcdir}/mingw-w64"

  git describe --long ${_commit} | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//g' | sed 's/11\.0\.0/11.0.1/g'
}

prepare() {
  cd "${srcdir}/mingw-w64"
}

build() {
  for _target in ${_targets}; do
    msg "Configuring ${_target} tools"
    for cur in ${_tools}; do
      mkdir -p ${srcdir}/${cur}-${_target} && cd ${srcdir}/${cur}-${_target}
      unset CC
      ${srcdir}/mingw-w64/mingw-w64-tools/${cur}/configure \
        --build=${CHOST} \
        --host=${_target} \
        --prefix=/opt/${_target}
      
      make
    done
  done
}

package() {
  for _target in ${_targets}; do
    msg "Installing ${_target} tools"
    for cur in ${_tools}; do
      cd ${srcdir}/${cur}-${_target}
      make DESTDIR=${pkgdir} install
    done
  done
}
