_realname=shim_executable
pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=2.3.r1.g65d5d07
pkgrel=1
pkgdesc="Make Shims for Executables (like Chocolatey and Scoop) (mingw-w64)"
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
url="https://github.com/jphilbert/shim_executable"
msys2_repository_url=$url
license=('spdx:MIT')
makedepends=(
  "${MINGW_PACKAGE_PREFIX}-cc"
  "git"
)
_commit='65d5d07ed12e789104a837fb344b19fc892b78ed'
source=("git+${url}.git#commit=$_commit"
        '001-cwd.patch'
        '002-widen.patch'
        'Makefile.msys2')
sha256sums=('8122bd3ebded0ae1f0da63b59b48a1f8489e8ab68af6daa2d61b41aa765f6c89'
            '4fcccf4a4823cbf7d8f4b0694c6857fba4cf5d32f9ec020d58ba65250c50dc60'
            '69917e5d62f000b62193d6736829d85105846f77099a5da07a9162bd93ed9312'
            '7728446adadcf1ac5d0518d08590385bc9545739da566eaa0c89d274ab70cfaa')
options=(!strip) # we do it on our own

pkgver() {
  cd "${_realname}"
  git describe --tags --long "${_commit}" | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//g'
}

prepare() {
  cd "${_realname}"
  patch -Np1 -i "${srcdir}/001-cwd.patch"
  patch -Np1 -i "${srcdir}/002-widen.patch"
}

build() {
  cd "${srcdir}/${_realname}"
  make -f "${srcdir}/Makefile.msys2"
}

package() {
  cd "${srcdir}/${_realname}"
  install -Dm755 shim_executable.exe "${pkgdir}${MINGW_PREFIX}/bin/shim_exec.exe"
  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
}
