# Maintainer: Joel Holdsworth <jholdsworth@nvidia.com>

_realname=patool
pkgbase=mingw-w64-python-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
pkgver=4.0.4
pkgrel=1
pkgdesc="Portable archive file manager and python library (mingw-w64)"
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
msys2_references=(
  'aur: patool'
  'purl: pkg:pypi/patool'
)
license=('spdx:GPL-3.0-or-later')
url='https://wummel.github.io/patool/'
msys2_repository_url='https://github.com/wummel/patool'
msys2_issue_tracker_url='https://github.com/wummel/patool/issues'
msys2_documentation_url='https://wummel.github.io/patool/'
depends=("file"
         "findutils"
         "${MINGW_PACKAGE_PREFIX}-python")
optdepends=("bsdcpio"
            "bsdtar"
            "cpio"
            "lzip"
            "lzop"
            "${MINGW_PACKAGE_PREFIX}-xz"
            "${MINGW_PACKAGE_PREFIX}-7zip"
            "${MINGW_PACKAGE_PREFIX}-binutils"
            "${MINGW_PACKAGE_PREFIX}-bzip3"
            "${MINGW_PACKAGE_PREFIX}-flac"
            "${MINGW_PACKAGE_PREFIX}-lz4")
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
             "${MINGW_PACKAGE_PREFIX}-python-installer"
	     "${MINGW_PACKAGE_PREFIX}-python-setuptools-reproducible")
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest")
options=('!strip')
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha256sums=('2f23e2d6513193c28061425d6ddf1f56561ae4003cbe2007fc6d051df273e09a')

build() {
  cp -r "${_realname}-${pkgver}" "build-${MSYSTEM}" && cd "build-${MSYSTEM}"
  ${MINGW_PREFIX}/bin/python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd "build-${MSYSTEM}"
  python -m pytest \
    --deselect tests/archives/test_bsdcpio.py::TestBsdcpio \
    --deselect tests/archives/test_7z.py::Test7z::test_7z \
    || warning "Tests failed"
}

package() {
  cd "build-${MSYSTEM}"

  MSYS2_ARG_CONV_EXCL="--prefix=" \
    python -m installer --prefix=${MINGW_PREFIX} \
    --destdir="${pkgdir}" dist/*.whl

  install -Dm644 COPYING "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/COPYING"
}
