# Maintainer: Tao Zuhong <taozuhong@hotmail.com>

_realname=mongo-c-driver
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=2.2.3
pkgrel=1
pkgdesc="libbson and libmongoc, the libraries constituting the MongoDB C Driver (mingw-w64)"
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
url="https://github.com/mongodb/mongo-c-driver"
msys2_repository_url='https://github.com/mongodb/mongo-c-driver'
license=("spdx:Apache-2.0")
msys2_references=(
  'anitya: 10712'
  'archlinux: mongo-c-driver'
  'cpe: cpe:2.3:a:mongodb:c_driver'
  'gentoo: dev-libs/mongo-c-driver'
)
depends=("${MINGW_PACKAGE_PREFIX}-zlib"
         "${MINGW_PACKAGE_PREFIX}-zstd"
         "${MINGW_PACKAGE_PREFIX}-snappy"
         "${MINGW_PACKAGE_PREFIX}-libutf8proc"
         "${MINGW_PACKAGE_PREFIX}-cc-libs")
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
             "${MINGW_PACKAGE_PREFIX}-cmake"
             "${MINGW_PACKAGE_PREFIX}-ninja"
             "${MINGW_PACKAGE_PREFIX}-python-sphinx")
# source=("mongo-c-driver-${pkgver}.tar.gz::https://github.com/mongodb/mongo-c-driver/archive/refs/tags/${pkgver}.tar.gz")
# curl -s https://pgp.mongodb.com/c-driver.asc | gpg --import
# validpgpkeys=('6DB55D8223FF44E49DCB981344E76C0565ABC463')  # MongoDB C Driver Release Signing Key <packaging@mongodb.com>
source=("${msys2_repository_url}/releases/download/${pkgver}/${_realname}-${pkgver}.tar.gz" #{,.asc}
        '001-implib-suffix.patch'
        '002-pkgconf-require-deps.patch'
        '003-pkgconf-winsock-and-noinc.patch')
sha256sums=('031b23793a0e0b5eacce0004d9de03c084f6d258f596d374c7a005726dc0206b'
            '3e00cd9d754e719d0c19867158ed5286ffa56de6b81f796f885cec1e3f8e1d70'
            '83a78751d0a89cd908213977f9adf0f20c67ff132a67ed0ec50570ddd5965277'
            '617f8df280d363557174eb098185af2bb048a59693ae0064070e8568b8fd4eb8')

prepare() {
  cd "${srcdir}/${_realname}-${pkgver}"
  # Trim any possible MSVC style lib suffixes throughout CMake file and prepend -l
  # This is ugly but we don't want to fix _generate_pkg_config_content
  sed -i -E 's/([[:alnum:]_-]+)\.lib(\W)/-l\1\2/g' "src/libmongoc/CMakeLists.txt"

  patch -Np1 -i "${srcdir}/001-implib-suffix.patch"
  patch -Np1 -i "${srcdir}/002-pkgconf-require-deps.patch"
  patch -Np1 -i "${srcdir}/003-pkgconf-winsock-and-noinc.patch"
}

build() {
  mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"

  declare -a _extra_config
  if check_option "debug" "n"; then
    _extra_config+=("-DCMAKE_BUILD_TYPE=Release")
  else
    _extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
  fi

  # TODO: libmongocrypt to ENABLE_CLIENT_SIDE_ENCRYPTION
  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
  "${MINGW_PREFIX}"/bin/cmake.exe \
    -GNinja \
    -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
    -DENABLE_STATIC=ON \
    -DENABLE_SHARED=ON \
    -DENABLE_EXAMPLES=OFF \
    -DENABLE_TESTS=OFF \
    -DENABLE_MAN_PAGES=ON \
    -DENABLE_ZSTD=ON \
    -DENABLE_ZLIB=SYSTEM \
    -DENABLE_SSL=WINDOWS \
    -DENABLE_SASL=SSPI \
    -DENABLE_MONGODB_AWS_AUTH=ON \
    -DENABLE_SNAPPY=ON \
    -DENABLE_CLIENT_SIDE_ENCRYPTION=OFF \
    -DUSE_BUNDLED_UTF8PROC=OFF \
    -DENABLE_SRV=ON \
    -DMONGOC_INSTALL_INCLUDEDIR=include \
    -DBSON_INSTALL_INCLUDEDIR=include \
    -DMONGOC_INSTALL_CMAKEDIR=lib/cmake/mongoc \
    -DBSON_INSTALL_CMAKEDIR=lib/cmake/bson \
    -DENABLE_UNINSTALL=OFF \
    "${_extra_config[@]}" \
    ../mongo-c-driver-${pkgver}

  "${MINGW_PREFIX}"/bin/cmake.exe --build .
}

package() {
  cd "${srcdir}/build-${MSYSTEM}"

  DESTDIR="${pkgdir}" "${MINGW_PREFIX}"/bin/cmake.exe --install .
}
