# Maintainer: Rui Abreu Ferreira <raf-ep@gmx.com>

_realname=bitop
pkgbase=mingw-w64-lua-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-lua51-${_realname}")
pkgver=1.0.3
pkgrel=1
arch=('any')
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
url='https://bitop.luajit.org/'
license=('MIT')
pkgdesc='C extension adding bitwise operations on numbers for Lua (mingw-w64)'
depends=("${MINGW_PACKAGE_PREFIX}-lua51")
makedepends=("${MINGW_PACKAGE_PREFIX}-lua51"
             "${MINGW_PACKAGE_PREFIX}-cc"
             "${MINGW_PACKAGE_PREFIX}-make"
             "${MINGW_PACKAGE_PREFIX}-pkgconf")

source=("https://bitop.luajit.org/download/LuaBitOp-${pkgver}.tar.gz")
sha256sums=('d514a3d2cefa76c8d11c1b9ec740d5fae316a9c9764e1e12ddea21e4982fab4b')

build() {
  cd LuaBitOp-${pkgver}
  mingw32-make \
    -f Makefile.mingw \
    "CC=${CC}" \
    "INCLUDES=$(pkgconf --cflags lua5.1)" \
    "LUADLLPATH=$(pkgconf --libs lua5.1)" \
    "RM=rm -f" \
    "LUA=lua5.1" \
    all
}

check() {
  cd LuaBitOp-${pkgver}
  mingw32-make \
    -f Makefile.mingw \
    "CC=${CC}" \
    "INCLUDES=$(pkgconf --cflags lua5.1)" \
    "LUADLLPATH=$(pkgconf --libs lua5.1)" \
    "RM=rm -f" \
    "LUA=lua5.1" \
    test
}

package() {
  cd LuaBitOp-${pkgver}
  install -Dm755 bit.dll "${pkgdir}${MINGW_PREFIX}/lib/lua/5.1/bit.dll"
}
