# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=libwmf
pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=0.2.15
pkgrel=1
pkgdesc="Library for Converting Metafile Images (mingw-w64)"
arch=('any')
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
url="https://wvWare.sourceforge.io/"
msys2_repository_url="https://github.com/caolanm/libwmf"
msys2_references=(
  "cpe: cpe:/a:francis_james_franklin:libwmf"
  "cpe: cpe:/a:wvware:libwmf"
)
license=("spdx:LGPL-2.0-or-later AND GPL-2.0-or-later")
depends=("${MINGW_PACKAGE_PREFIX}-freetype"
         "${MINGW_PACKAGE_PREFIX}-glib2"
         "${MINGW_PACKAGE_PREFIX}-gdk-pixbuf2"
         "${MINGW_PACKAGE_PREFIX}-libjpeg"
         "${MINGW_PACKAGE_PREFIX}-libpng"
         "${MINGW_PACKAGE_PREFIX}-libxml2"
         "${MINGW_PACKAGE_PREFIX}-zlib")
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
             "${MINGW_PACKAGE_PREFIX}-autotools")
source=(https://github.com/caolanm/libwmf/archive/v${pkgver}/${_realname}-${pkgver}.tar.gz
        https://patch-diff.githubusercontent.com/raw/caolanm/libwmf/pull/24.patch
        https://patch-diff.githubusercontent.com/raw/caolanm/libwmf/pull/23.patch
        https://patch-diff.githubusercontent.com/raw/caolanm/libwmf/pull/25.patch
        https://patch-diff.githubusercontent.com/raw/caolanm/libwmf/pull/26.patch)
sha256sums=('379ae041dd53ab35f55c9b73a78a31f1ce530e925023c31607b05f2199d867e6'
            '900ea581c69db14af7bc14f8045310da94c4e015a466d473a0723df269c07039'
            'f8c465f3a205abb439f4bdd794ad269605051706739408bd8e2c1919cb5a0d4e'
            '22ec5f0ea0de58f19e12b99ebb510236e14dde07ff8eb70698c6fb753b62df47'
            '9eb4ccf356225551101ab8b8de7cc9befc8e799226bdeb851e113bb4cc9297f5')

prepare() {
  cd "${srcdir}"/${_realname}-${pkgver}
  patch -p1 -i "${srcdir}"/24.patch
  patch -p1 -i "${srcdir}"/23.patch
  patch -p1 -i "${srcdir}"/25.patch
  patch -p1 -i "${srcdir}"/26.patch

  libtoolize --force --copy --install
  autoreconf -fiv -Ipatches
}

build() {
  mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"

  "${srcdir}"/${_realname}-${pkgver}/configure \
    --prefix=${MINGW_PREFIX} \
    --build=${MINGW_CHOST} \
    --host=${MINGW_CHOST} \
    --target=${MINGW_CHOST} \
    --enable-shared \
    --disable-static \
    --with-libxml2 \
    --without-x

  make
}

package() {
  cd "${srcdir}/build-${MSYSTEM}"
  make DESTDIR="$pkgdir" install
  find "${pkgdir}${MINGW_PREFIX}" -name '*.def' -o -name '*.exp' | xargs -rtl1 rm
  rm "${pkgdir}${MINGW_PREFIX}"/lib/gdk-pixbuf-2.0/2.*/loaders/*.dll.a

  # fix .pc file
  sed -s "s|$(cygpath -m ${MINGW_PREFIX})|${MINGW_PREFIX}|g" -i "${pkgdir}${MINGW_PREFIX}"/lib/pkgconfig/libwmf.pc
}
