# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_realname=libdmtx
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=0.7.8
pkgrel=1
pkgdesc='A software for reading and writing Data Matrix 2D barcodes (mingw-w64)'
url='https://libdmtx.sourceforge.net/'
msys2_repository_url='https://github.com/dmtx/libdmtx'
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
license=('spdx:LicenseRef-libdmtx')
depends=()
makedepends=(
  "git"
  "${MINGW_PACKAGE_PREFIX}-cc"
  "${MINGW_PACKAGE_PREFIX}-cmake"
  "${MINGW_PACKAGE_PREFIX}-ninja"
)
source=(git+https://github.com/dmtx/libdmtx#tag=v${pkgver})
sha256sums=('0ad1fcf472cc785fb0f5ecb055a2568384fcb85a09175cb176b24bf76adaaa48')

build() {
  mkdir -p "build-${MSYSTEM}" && cd "build-${MSYSTEM}"

  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
    cmake \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
      -DCMAKE_DLL_NAME_WITH_SOVERSION=ON \
      ../"${_realname}"

  cmake --build .
}

package() {
  cd "build-${MSYSTEM}"

  DESTDIR="${pkgdir}" cmake --install .

  install -Dm644 "${srcdir}/${_realname}/LICENSE" -t "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}"
}
