# Maintainer: Jing Yufei <master-hash@outlook.com>

_realname=gitu
pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=0.41.0
pkgrel=1
pkgdesc='A TUI Git client inspired by Magit (mingw-w64)'
msys2_references=(
  'anitya: 387618'
  'archlinux: gitu'
  'purl: pkg:cargo/gitu'
)
url='https://github.com/altsem/gitui'
msys2_repository_url='https://github.com/altsem/gitui'
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
license=('spdx:MIT')
depends=("${MINGW_PACKAGE_PREFIX}-libgit2")
makedepends=("${MINGW_PACKAGE_PREFIX}-rust"
             "${MINGW_PACKAGE_PREFIX}-pkgconf"
             'git')
source=("git+https://github.com/altsem/gitu.git#tag=v${pkgver}")
sha256sums=('9b1ade98026226a8a8f95ef1a1536c0ead6dd050b5f879cd096e2af42aa6772d')

prepare() {
  cd "${_realname}"

  cargo fetch --locked --target "${RUST_CHOST}"
}

build() {
  cd "${_realname}"

  cargo build \
    --frozen \
    --release
}

check() {
  cd "${_realname}"

  cargo test \
    --frozen \
    --release
}

package() {
  cd "${_realname}"

  cargo install \
    --frozen \
    --offline \
    --no-track \
    --path . \
    --root "${pkgdir}${MINGW_PREFIX}"

  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE"
}
