# Maintainer: Sahil Gautam <printfdebugging@gmail.com>

_realname=bear
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=4.1.1
pkgrel=2
pkgdesc='A tool that generates a compilation database for clang tooling (mingw-w64)'
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url='https://github.com/rizsotto/Bear'
msys2_repository_url='https://github.com/rizsotto/Bear'
msys2_references=(
    'archlinux: bear'
)
license=('spdx:GPL-3.0-or-later')
makedepends=("${MINGW_PACKAGE_PREFIX}-rust")
options=('!strip')
source=("${url}/archive/${pkgver}/${_realname}-${pkgver}.tar.gz")
sha256sums=('58665614e59f3b7f7127e6a6fe4c94ddc64b81e80a4c160ecbd7e44b9171308f')

prepare() {
    cd "${_realname}-${pkgver}"

    cargo fetch --locked --target "${RUST_CHOST}"
}

build() {
    cd "${_realname}-${pkgver}"

    cargo build --frozen --release
}

check() {
    cd "${_realname}-${pkgver}"

    cargo test --frozen --release
}

package() {
    cd "${_realname}-${pkgver}"

    DESTDIR="${pkgdir}" PREFIX="${MINGW_PREFIX}" sh scripts/install.sh
}
