$!make_sauter_pk.com
$! V1.5  13-NOV-1994
$!
$! (c) Copyright 1992, 1993, 1994 J"org Knappen
$!
$! Benutzung:
$! @make_sauter_pk MODENAME FONTNAME SIZELIST
$! Beispiel:
$! @make_sauter_pk laserjet cmr 5,6,7,8,9,10,11,12,14,17,20,25
$!
$! Modell:
$! $write/file=FONTNAME'SIZE.mf "design_size=EXACTSIZE; input BFONTNAME"
$! $mf "\mode=MODENAME;  input FONTNAME'SIZE"
$! $gftopk FONTNAME'SIZE.DPIgf
$!
$! Hierbei ist MODENAME zum Beispiel laserjet oder dec_lnp
$! BFONTNAME zum Beispiel b-cmr
$! EXACTSIZE zum Beispiel 14.4
$! SIZE      zum Beispiel 14
$!
$! Gehe zum gew"unschten Verzeichnis und initialisiere TeX und METAFONT
$! set def $diskx:[scratch.mf]
$! env tex
$!
$! Fahre fort bei Fehler 
$ on error then continue
$! Abbruch mit Ctrl-Y
$ on control_y then goto ctrly
$!
$! Gib etwas Hilfe
$ if P1 .eqs. "?" then goto HILFE
$ if P3 .eqs. "" then goto HILFE
$ if P4 .nes. "" then goto HILFE
$!
$! Initialisierung
$ MODENAME=f$edit(P1,"lowercase")
$ FONTNAME=f$edit(P2,"lowercase")
$ BFONTNAME=f$fao("b-!AS",FONTNAME)
$ DPI="300"
$! 300 dpi ist die Voreinstellung, aber der laserjetIV hat 600 dpi 
$! Aufl"osung
$ if MODENAME .eqs. "ljiv" then DPI="600"
$!
$! Jetzt kommt die Schleife zur Berechnung der Fonts
$ next=0
$ schleife:
$ SIZE=f$element(next,",",p3) 
$ if SIZE .eqs. "," then $goto ausgang
$ EXACTSIZE=SIZE
$ if SIZE .eqs. 11 then EXACTSIZE="10.95"
$ if SIZE .eqs. 14 then EXACTSIZE="14.4"
$ if SIZE .eqs. 17 then EXACTSIZE="17.28"
$ if SIZE .eqs. 20 then EXACTSIZE="20.74"  ! war: 20.736
$ if SIZE .eqs. 25 then EXACTSIZE="24.88"  ! war: 24.8832
$ if SIZE .eqs. 30 then EXACTSIZE="29.86"  ! war: 29.85976  
$ if SIZE .eqs. 36 then EXACTSIZE="35.83"  ! war: 35.831712
$!
$ GFDATEI=f$fao("!AS.!ASgf",FONTNAME,DPI)
$ PKDATEI=f$fao("!AS!AS.pk",FONTNAME,SIZE)
$ ORITFMDATEI=f$fao("!AS.tfm",BFONTNAME)
$ TFMDATEI=f$fao("!AS!AS.tfm",FONTNAME,SIZE)
$ MFDATEI=f$fao("!AS!AS.mf",FONTNAME,SIZE)
$! 
$! Schreibe eine .mf-Datei f"ur den zu erzeugenden Font
$ open/write file 'MFDATEI
$ write file "design_size=''EXACTSIZE';"
$ write file "input ''BFONTNAME';"
$ close file
$!
$ command=f$fao("mf/batch ""\mode:=!AS; input !AS""",MODENAME,MFDATEI)
$! write sys$output command
$ on error then continue
$ command
$!
$ gftopk 'f$fao("!AS!AS.!ASgf",FONTNAME,SIZE,DPI)
$!
$! Schlie"se die Schleife
$ next=next+1
$ goto schleife
$!
$! Hilfe...
$ HILFE:
$ write sys$output "Usage: @make_sauter_pk MODENAME FONTNAME SIZELIST"
$ write sys$output -
  "Example: @make_sauter_pk laserjet cmr 5,6,7,8,9,10,11,12,14,17,20,25"
$! Normales Ende
$ ausgang:
$ exit
$! Ende durch Ctrl-Y
$ ctrly:
$ exit 1